;This program will search for bass tracks and then replace the bass patch.
;It will also replace the NoteLow and NoteHigh to get the best pitch range for this bass
Define BassTrack Numeric
ForEachStyle
  PrintLine StyleName
  ForEachTrack
    ;Determine wether this is a track played with a bass patch
    Let BassTrack = 0
    If DrumTrack = 0    
      ForEachPart
        ForEachEvent
          If EventType = 4 ;patch
            If DataByte1 >= 32 
              If DataByte1 <= 39 ;patch 32-39 is bass
                Let BassTrack = 1  
              EndIf
            EndIf
          EndIf
        NextEvent
      NextPart
    EndIf
    If BassTrack = 1
      ;Modify pitch range, bank and patch
      ForEachPart
        Let NoteLow = 20   ; *** CUSTOMIZE HERE ****
        Let NoteHigh = 40  ; *** CUSTOMIZE HERE ****
        ForEachEvent
          If EventType = 3 ; Controller
            If DataByte1 = 0 ;Bank
              DeleteEvent
            EndIf
            If DataByte1 = 32 ;Bank
              DeleteEvent
            Endif
          Endif
          If EventType = 4 ; Patch
            DeleteEvent
            Let EventType = 3  ;Controller 0
            Let DataByte1 = 0
            Let DataByte2 = 0  ; *** CUSTOMIZE HERE ****
            InsertEvent
            Let EventType = 3  ;Controller 32
            Let DataByte1 = 32
            Let DataByte2 = 17 ; *** CUSTOMIZE HERE ****
            InsertEvent
            Let EventType = 4  ;Patch
            Let DataByte1 = 35 ; *** CUSTOMIZE HERE ****
            InsertEvent
          EndIf
        NextEvent
      NextPart
    EndIf
  NextTrack
  SaveStyle
NextStyle